
**Year-over-year growth**

Year-over-year compares a time period to its equivalent in the previous year. In this example, data is available until August 2009. For this reason, Sales PY shows numbers related to the year 2009 considering transactions only from before August 2008. Figure 3 shows that the Sales Amount of 2008 is 9,927,582.99, whereas Sales PY for 2009 returns 6,166,534.30 because the measure involves sales only up to August 2008.



Sales PY removes all the filters from the Date table; it filters the Year column by using the previous year, and by using [***VALUES***](https://dax.guide/values/?aff=dax-patterns) it retrieves the months visible in the current filter context to then filter the Month Number column. The Date table must hold only the months with sales, instead of holding all the months of the year as required by the standard time intelligence functions in DAX. This way, any direct or indirect selection of months is applied to the previous year:

Sales PY :=

VAR CurrentYearNumber = SELECTEDVALUE ( 'Date'[Year] )

VAR PreviousYearNumber = CurrentYearNumber - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year] = PreviousYearNumber,

        VALUES ( 'Date'[Month Number] )

    )

RETURN

    Result

Year-over-year growth is computed as an amount in Sales YOY, and as a percentage in Sales YOY %. Both measures use Sales PY to take into account dates only up to August 2009:

Sales YOY :=

VAR ValueCurrentPeriod = [Sales Amount]

VAR ValuePreviousPeriod = [Sales PY]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YOY % :=


DIVIDE (

    [Sales YOY],

    [Sales PY]

)

Year-over-year compares a period to the equivalent period in the previous year.

Sales PY uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) and filters Date[DateWithSales] to guarantee a fair comparison of the last period with data. The year-over-year growth is computed as an amount in Sales YOY, and as a percentage in Sales YOY %. Both measures use Sales PY to only consider dates up to August 15, 2009:

Sales PY :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        CALCULATETABLE (

            DATEADD ( 'Date'[Date], -1, YEAR ),

            'Date'[DateWithSales] = TRUE

        )

    )

)

Sales YOY :=

VAR ValueCurrentPeriod = [Sales Amount]

VAR ValuePreviousPeriod = [Sales PY]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YOY % :=

DIVIDE (

    [Sales YOY],

    [Sales PY]

)

Sales PY can also be written using [**SAMEPERIODLASTYEAR**](https://dax.guide/sameperiodlastyear/?aff=dax-patterns). [**SAMEPERIODLASTYEAR**](https://dax.guide/sameperiodlastyear/?aff=dax-patterns) is easier to read, but it does not offer any performance benefit. This is because internally, it is translated into the [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) function used in previous formulas:

Sales PY (2) :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        CALCULATETABLE (

            SAMEPERIODLASTYEAR ( 'Date'[Date] ),

            'Date'[DateWithSales] = TRUE

        )

    )

)